Contenido

# CONTAR.SI.CONJUNTO

Devuelve el recuento de celdas que cumplen los criterios en varios intervalos.

Esta función está disponible desde la versión 4.0 de LibreOffice.

### Sintaxis

CONTAR.SI.CONJUNTO(Rango; Criterio[; Rango2; Criterio2][; ... ; [Rango127; Criterio127]])

Intervalo 1: argumento requerido. Es un intervalo de celdas, el nombre de un intervalo con nombre o la etiqueta de una columna o una fila a que se aplicará el criterio correspondiente.

Criterio: Un criterio es una única celda Referencia, Número o Texto. Se utiliza en las comparaciones con el contenido de las celdas.

Una referencia a una celda vacía se interpreta como el valor numérico 0.

Una expresión coincidente puede ser:

- Un número o valor lógico. Un contenido de celda que coincida con el número o valor lógico.

- Un valor que comienza con un comparador (<, <=, =, >, >=, <>).

  En el caso de =, si el valor está vacío, coincide con las celdas vacías.

  En el caso de <>, si el valor está vacío coincide con las celdas no vacías.

  Para <>, si el valor no está vacío coincide con cualquier contenido de la celda excepto el valor, incluyendo las celdas vacías.

  Nota"=0" no coincide con las celdas vacías.

  Para = y <>, si el valor no está vacío y no puede interpretarse como un tipo Número o uno de sus subtipos y la propiedad Los criterios de búsqueda = y <> deben aplicarse a las celdas completas está marcada, la comparación se realiza contra todo el contenido de la celda, si no está marcada, la comparación se realiza contra cualquier subparte del campo que coincida con los criterios. Para = y <>, si el valor no está vacío y no puede interpretarse como un tipo de Número o se aplica uno de sus subtipos.

- Otro valor de texto. Si la propiedad Criterios de búsqueda = y <>debe aplicarse a celdas completas es verdadera, la comparación es con todo el contenido de la celda, si es falso, la comparación es contra cualquier subparte del campo que coincida con los criterios. La expresión puede contener texto, números, expresiones regulares o comodines (si está activado en las opciones de cálculo).

Intervalo2: opcional. Intervalo2 y todos los argumentos siguientes tienen el mismo significado que Intervalo1.

Criterio 2 – Opcional. Criterio2 y todos los promedios significan lo mismo que Criterio.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

Rango, Rango2, ... y Criterio, Criterio2, ... deben tener el mismo tamaño, de lo contrario la función devuelve error:502 - Argumento no válido.

La relación lógica entre los criterios puede definirse como Y lógico (conjunción). En otras palabras, si y sólo si se cumplen todos los criterios dados, un valor de la celda correspondiente delFunción_Rangose tiene en cuenta en el cálculo.

La función puede tener hasta 255 argumentos, lo que significa que es posible especificar hasta 127 intervalos de criterios y sus criterios correspondientes.

Si una celda contiene VERDADERO se tratará como 1; si contiene FALSO, como 0 (cero).

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

#### Ejemplo

Tenga en cuenta la tabla siguiente

| A | B | C
1 | Nombre de producto | Ventas | Ingresos
2 | lápiz | 20 | 65
3 | pluma | 35 | 85
4 | cuaderno | 20 | 190
5 | libro | 17 | 180
6 | estuche | no | no

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.

#### Uso simple

=CONTAR.SI.CONJUNTO(B2:B6;">=20")

Cuenta la cantidad de filas del intervalo B2:B6 con valores mayores o iguales que 20. Devuelve 3 porque las filas quinta y sexta no cumplen con el criterio.

=CONTAR.SI.CONJUNTO(B2:B6;">=20";C2:C6;">70")

Cuenta la cantidad de filas que contiene simultáneamente valores mayores que 70 en el intervalo C2:C6 y valores mayores o iguales que 20 en el intervalo B2:B6. Devuelve 2 porque las filas segunda, quinta y sexta no cumplen con al menos un criterio.

#### Uso de expresiones regulares y funciones anidadas

Para que estos ejemplos funcionen como se han descrito, asegúrese de que esté seleccionada la opción Activar expresiones regulares en fórmulas, la cual se halla en LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

=CONTAR.SI.CONJUNTO(B2:B6;"[:alpha:]*")

Cuenta la cantidad de filas del intervalo B2:B6 que contienen solamente símbolos alfabéticos. Devuelve 1 porque solo la sexta fila cumple con el criterio.

=CONTAR.SI.CONJUNTO(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Contabiliza las filas en el intervalo B2:B6, excluyendo las filas con los valores mínimo y máximo de este intervalo. Devuelve 2, porque las filas tercera, quinta y sexta no cumplen con por lo menos un criterio.

=CONTAR.SI.CONJUNTO(A2:A6;"cla.*";B2:B6;"<"&MAX(B2:B6))

Cuenta la cantidad de filas que corresponde a todas las celdas del intervalo A2:A6 que comienzan por «cla» y a todas las celdas del intervalo B2:B6 con la excepción de su máximo. Devuelve 1 porque solo la segunda fila cumple con todos los criterios.

#### Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, se puede especificar en una celda separada y usar la referencia a esa celda en la condición de la función CONTAR.SI.CONJUNTO. Por ejemplo, la función anterior puede reescribirse así:

=CONTAR.SI.CONJUNTO(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = pen, la función devuelve 1, porque el enlace a la celda se sustituye por su contenido y funciona como la función anterior.

Temas relacionados

COUNTIFS wiki page.

CONTAR, CONTAR.SI, CONTAR.BLANCO, CONTARA

CONTAR.SI.CONJUNTO, MIN.SI.CONJUNTO, Función MAX.SI.CONJUNTO, PROMEDIO.SI.CONJUNTO, SUMAR.SI.CONJUNTO

Lista de expresiones regulares